home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO018.dsk
/
FORMATTER.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
1KB
|
43 lines
100 REM VOLUME FORMATTER
110 REM BY KEITH FALKNER
111 REM VERSION 1.1, AUG 86.
120 :
130 REM DO NOT CHANGE THIS, BECAUSE
140 REM THE MACHINE LANGUAGE ROUTINE
150 REM WILL MOVE AND BE UNUSABLE.
160 :
170 IF PEEK(175) +256 * PEEK(176) = 6656 GOTO 250
180 PRINT "The BASIC part of this program has been"
190 PRINT "changed, so the machine-language part"
200 PRINT "is no longer at the right address."
210 PRINT "The program has been destroyed!"
220 STOP : GOTO 220
230 :
240 REM MEMORY USAGE:
250 VY = 704: REM PARAMETERS:
260 REM SLOT,DRIVE,VOLUME,RESULT
270 VM = 3072: REM $0C00
280 :
290 IF VS >0 AND VS <8 GOTO 320
300 INPUT "SLOT NUMBER (1-7):";VS$
310 VS = VAL(VS$): GOTO 290
320 IF VD = 1 OR VD = 2 GOTO 350
330 INPUT "DRIVE NUMBER (1/2):";VD$
340 VD = VAL(VD$): GOTO 320
350 VL = LEN(VN$)
360 IF VL >0 AND VL <16 GOTO 400
370 INPUT "VOLUME NAME /";VN$
380 IF LEFT$(VN$,1) = "/" THEN VN$ = MID$ (VN$,2)
390 GOTO 350
400 VY = 704: REM $2C0
410 POKE VY +0,VS: REM SLOT
420 POKE VY +1,VD: REM DRIVE
430 POKE VY +2,VL: REM LENGTH
440 FOR V = 1 TO VL:Z = ASC( MID$ (VN$,V,1))
450 IF Z = > ASC("a") AND Z < = ASC("z") THEN Z = Z -32
460 POKE VY +2 +V,Z: NEXT
470 CALL VM: REM FORMAT DISK
480 VR = PEEK(VY +18): REM RESULT
490 IF VR THEN PRINT "OOPS! RETURN-CODE IS "VR"."
500 IF PN$ = "" THEN END
510 PRINT CHR$(4)"CHAIN"PN$